Manufaturação industrial
Internet das coisas industrial | Materiais industriais | Manutenção e reparo de equipamentos | Programação industrial |
home  MfgRobots >> Manufaturação industrial >  >> Manufacturing Technology >> Processo de manufatura

Lâmpada de Mesa Reativa a Áudio com Arduino Nano

Componentes e Materiais

Ferramentas Necessárias

Aplicativos e Serviços Online

Sobre este Projeto

OLÁ MUNDO!!

Neste projeto, faremos uma luminária bonita que dança com sons e músicas, usando componentes simples e programação básica Arduino. Fica incrível na mesa durante jogos, música ou qualquer som. Vamos lá!

Baseado no youtuber "Natural Nerd". Esta é minha versão. Créditos a eles.

Link YouTube

PASSO 1: MATERIAIS PRINCIPAIS

Para o visual desejado, usei:

Total aproximado: R$ 83,30 (varia por loja). A faixa LED foi o item mais caro.

PASSO 2: ALIMENTAÇÃO DOS COMPONENTES

Lâmpada de Mesa Reativa a Áudio com Arduino Nano

Alimentação direta via USB do Arduino Nano no PC. Se usar fonte externa AC/DC, use módulo step-down para 5V — senão risco de queimar Arduino e componentes.

O módulo detector de som fornece sinal analógico ao Arduino para controlar os LEDs RGB. Ambos operam a 5V. Usei step-down de 12V para 5V, mas fonte 5V direta é mais simples. Ligue VIN do Arduino e do detector ao positivo; GND ao negativo. Conecte também alimentação da faixa LED à fonte.

PASSO 3: DETECTOR & FAIXA LED

Lâmpada de Mesa Reativa a Áudio com Arduino Nano

Após alimentação, conecte os módulos entre si:

Use tubo termorretrátil nos cabos para evitar curtos em espaço apertado. Siga o esquemático fornecido.

PASSO 4: CARREGANDO O CÓDIGO

A parte mais importante é o código — transforma o projeto de "legal" para "incrível". Use o código fornecido. Princípio: mapear valor analógico do sensor para quantidade de LEDs acesos.

PASSO 5: PREPARANDO O GABINETE

Lâmpada de Mesa Reativa a Áudio com Arduino Nano
  1. Tampa: A tampa era vidro, não acrílico. Fiz tampa de placa de espuma: marquei diâmetro com caneta molhada no papel, recortei.
  2. Remover vidro: CUIDADO! Cubra o pote com saco plástico grosso para evitar estilhaços. Faça em área aberta. Remova todos os cacos.
  3. Fixar tampa de espuma: Centralize na tampa do pote; ajuste para ficar firme.
  4. Acessibilidade: Usei mini protoboard no centro da tampa. Furos para cabos do detector (fora do pote) e USB do Arduino.
  5. Tubo PVC: Marquei com fita, cortei no comprimento do pote. Enrolei a faixa LED em espiral no tubo, escondendo cabos dentro. Fixei tubo na protoboard com cola quente/ fita dupla face.
  6. Detector de som: Colocado fora da tampa (melhor captação). Conectado conforme esquemático.
  7. Arduino vertical: Para fácil conexão USB através do furo na tampa.
Lâmpada de Mesa Reativa a Áudio com Arduino Nano

Projeto concluído! Demorou um pouco com tentativas e erros, mas funcionou.

Código

Código para Arduino — LEDs reagem ao som detectado.

#include <FastLED.h>

/** CONFIGURAÇÃO BÁSICA **/
#define NUM_LEDS 60        // quantidade de LEDs
#define LED_PIN 6          // pino de controle dos LEDs
#define ANALOG_READ 0      // pino de leitura do sensor (A0)
#define MIC_LOW 0.0        // valor mínimo confirmado do microfone
#define MIC_HIGH 200.0     // valor máximo confirmado do microfone

/** OUTRAS CONFIGURAÇÕES **/
#define AVGLEN 5           // quantas leituras anteriores afetam média operacional
#define LONG_SECTOR 20     // janela para detectar pico/alto (ex: batida música)
#define HIGH_MODE 3
#define NORMAL_MODE 2
#define MSECS 30 * 1000    // tempo para resetar média da música
#define CYCLES MSECS / DELAY
#define DEV_THRESH 0.8     // tolerância de desvio da média
#define DELAY 1            // delay do loop (ms)

float fscale(float originalMin, float originalMax, float newBegin, float newEnd, float inputValue, float curve);
void insert(int val, int *avgs, int len);
int compute_average(int *avgs, int len);
void visualize_music();

int curshow = NUM_LEDS;
int mode = 0;
int songmode = NORMAL_MODE;
unsigned long song_avg = 0;
int iter = 0;
float fade_scale = 1.2;
CRGB leds[NUM_LEDS];
int avgs[AVGLEN] = {-1};
int long_avg[LONG_SECTOR] = {-1};

struct time_keeping { unsigned long times_start; short times; };
struct color { int r, g, b; };
struct time_keeping high;
struct color Color;

void setup() {
  Serial.begin(9600);
  FastLED.addLeds<NEOPIXEL, LED_PIN>(leds, NUM_LEDS);
  for (int i = 0; i < NUM_LEDS; i++) leds[i] = CRGB(0, 0, 255);
  FastLED.show(); delay(1000);

  // bootstrap média com valores baixos
  for (int i = 0; i < AVGLEN; i++) insert(250, avgs, AVGLEN);

  high.times = 0; high.times_start = millis();
  Color.r = 0; Color.g = 0; Color.b = 1;
}

void loop() {
  switch (mode) {
    case 0: visualize_music(); break;
    default: break;
  }
  delay(DELAY);
}

void check_high(int avg) {
  if (avg > (song_avg / iter * 1.1)) {
    if (high.times != 0) {
      if (millis() - high.times_start > 200.0) { high.times = 0; songmode = NORMAL_MODE; }
      else { high.times_start = millis(); high.times++; }
    } else { high.times++; high.times_start = millis(); }
  }
  if (high.times > 30 && millis() - high.times_start < 50.0) songmode = HIGH_MODE;
  else if (millis() - high.times_start > 200) { high.times = 0; songmode = NORMAL_MODE; }
}

void visualize_music() {
  int sensor_value = analogRead(ANALOG_READ);
  if (sensor_value == 0) return;

  float mapped = fscale(MIC_LOW, MIC_HIGH, MIC_LOW, (float)MIC_HIGH, (float)sensor_value, 2.0);
  int avg = compute_average(avgs, AVGLEN);
  if (((avg - mapped) > avg * DEV_THRESH)) return;

  insert((int)mapped, avgs, AVGLEN);
  insert(avg, long_avg, LONG_SECTOR);

  song_avg += avg; iter++;
  if (iter > CYCLES) { song_avg = song_avg / iter; iter = 1; }
  int longavg = compute_average(long_avg, LONG_SECTOR);

  check_high(longavg);

  if (songmode == HIGH_MODE) { fade_scale = 3; Color.r = 5; Color.g = 3; Color.b = -1; }
  else { fade_scale = 2; Color.r = -1; Color.b = 2; Color.g = 1; }

  curshow = fscale(MIC_LOW, MIC_HIGH, 0.0, (float)NUM_LEDS, (float)avg, -1);

  for (int i = 0; i < NUM_LEDS; i++) {
    if (i < curshow) {
      leds[i].r = constrain(leds[i].r + Color.r, 0, 255);
      leds[i].g = constrain(leds[i].g + Color.g, 0, 255);
      leds[i].b = constrain(leds[i].b + Color.b, 0, 255);
    } else {
      leds[i] = CRGB(leds[i].r / fade_scale, leds[i].g / fade_scale, leds[i].b / fade_scale);
    }
  }
  FastLED.show();
}

int compute_average(int *avgs, int len) {
  int sum = 0;
  for (int i = 0; i < len; i++) sum += avgs[i];
  return sum / len;
}

void insert(int val, int *avgs, int len) {
  for (int i = 0; i < len; i++) {
    if (avgs[i] == -1) { avgs[i] = val; return; }
  }
  for (int i = 1; i < len; i++) avgs[i-1] = avgs[i];
  avgs[len-1] = val;
}

float fscale(float originalMin, float originalMax, float newBegin, float newEnd, float inputValue, float curve) {
  // Função de mapeamento com curva (não-linear) - do site Arduino
  float OriginalRange = originalMax - originalMin;
  float NewRange = (newEnd > newBegin) ? newEnd - newBegin : newBegin - newEnd;
  bool invFlag = (newEnd <= newBegin);
  if (curve > 10) curve = 10;
  if (curve < -10) curve = -10;
  curve = (curve * -.1);
  curve = pow(10, curve);
  if (inputValue < originalMin) inputValue = originalMin;
  if (inputValue > originalMax) inputValue = originalMax;
  float zeroRefCurVal = inputValue - originalMin;
  float normalizedCurVal = zeroRefCurVal / OriginalRange;
  if (originalMin > originalMax) return 0;
  float rangedValue = invFlag ? newBegin - (pow(normalizedCurVal, curve) * NewRange)
                              : (pow(normalizedCurVal, curve) * NewRange) + newBegin;
  return rangedValue;
}

Esquemático

Lâmpada de Mesa Reativa a Áudio com Arduino Nano

Processo de manufatura

  1. Detector de Idiomas TinyML com Edge Impulse no Arduino Nano 33 BLE Sense
  2. Construa um Jogo em Tempo Real com Giroscópio: Arduino Nano + Sensor MPU-6050
  3. Dados Digital com Arduino: Gere Números Aleatórios 1-6 em LCD 16x2
  4. Construa um Homem de Ferro com Arduino: Componentes, Sensores e Guia Passo a Passo
  5. Find Me: Localizador Inteligente de Objetos com Arduino e Bluetooth
  6. Como Reproduzir Áudio com Arduino UNO e DFPlayer Mini – Guia Passo a Passo
  7. Controlador de Umidificador DIY com Arduino e Relé – Configuração Segura de Alta Tensão
  8. Medição de Distância em Tempo Real com Sonar Arduino e Visualização no Processing
  9. MobBob: Construa Seu Próprio Robô Arduino, Controlado via Smartphone Android
  10. Jogo Pong Neon em Matriz NeoPixel com Arduino Nano