Manufaturação industrial
Internet das coisas industrial | Materiais industriais | Manutenção e reparo de equipamentos | Programação industrial |
home  MfgRobots >> Manufaturação industrial >  >> Manufacturing Technology >> Processo de manufatura

Presente de Dia dos Namorados: Contador DIY de Dias Juntos

Componentes e Materiais

Componente Quantidade
Relógio de Tempo Real (RTC) DS3231 1
Display de 7 segmentos 4 dígitos KYX-5461AS para Arduino 1
Protoboard (genérica) 1
Jumpers (genéricos) 1
Arduino UNO 1
Resistor 1k ohm 1

Sobre o Projeto

Em 2017, por volta de setembro, eu estava começando meu segundo ano na universidade e conheci uma garota incrível. Mudei-me para uma acomodação com ela e seus amigos e acabamos dividindo um andar da casa, só nós dois. Conversamos, tornamo-nos melhores amigos e, após alguns meses, começamos a namorar. O dia em que começamos a namorar foi 10/12/2017 (formato UK).

Quase um ano depois, eu estava tentando decidir o que fazer para nosso aniversário e tive uma ideia: criar algo usando o que estava estudando (eletrônica). Decidi fazer um contador que exibisse o número de dias desde que começamos a namorar e colocá-lo em um porta-retratos com uma foto nossa.

Se você chegou aqui procurando uma ideia para seu aniversário ou apenas navegando, este é um projeto divertido e vou compartilhar tudo para que você possa fazer o seu.

A parte mais difícil é o código. Criei um modelo de exemplo que, ao compilar e carregar, exibe a data do meu relacionamento, mas adicionei comentários no código para que você possa inserir sua própria data.

Divirta-se!

Código

DaysCounter.ino

Para este projeto, você precisará:

Salve ambas as bibliotecas na pasta libraries onde a Arduino IDE está instalada. Em seguida, abra a IDE, vá em Sketch → Incluir Biblioteca → Adicionar Biblioteca .ZIP.

Para ajustar a data: na linha 7, dentro dos parênteses, está (2017, 12, 9, 0, 0, 0). Altere os três primeiros números para a data do seu relacionamento (ano, mês, dia). Exemplo: 2014, 4, 6.

Compile e faça o upload. Se tudo estiver correto, o display mostrará a quantidade de dias que vocês estão juntos.

#include <RTClib.h>
#include <SevSeg.h>

SevSeg sevseg;
RTC_DS3231 rtc;
DateTime dtBegin(2017, 12, 9, 0, 0, 0); // AJUSTE A DATA AQUI!
TimeSpan tsPassed;

void showInfo(const DateTime& dt) {
  Serial.print("NOW:");
  Serial.print(dt.year(), DEC); Serial.print('/');
  Serial.print(dt.month(), DEC); Serial.print('/');
  Serial.print(dt.day(), DEC); Serial.print(' ');
  Serial.print(dt.hour(), DEC); Serial.print(':');
  Serial.print(dt.minute(), DEC); Serial.print(':');
  Serial.print(dt.second(), DEC);
  Serial.print("\tPASSED:");
  Serial.print(tsPassed.days(), DEC); Serial.print(' ');
  Serial.print(tsPassed.hours(), DEC); Serial.print(':');
  Serial.print(tsPassed.minutes(), DEC); Serial.print(':');
  Serial.print(tsPassed.seconds(), DEC);
  Serial.println();
}

void delayWithUpdate(uint32_t parDelay) {
  uint32_t started = millis();
  while (millis() < started + parDelay) {
    sevseg.refreshDisplay();
  }
}

void setup() {
  Serial.begin(9600);
  Serial.println(__TIME__);

  if (!rtc.begin()) {
    Serial.println("RTC não encontrado");
    while (1);
  }
  delay(1000);

  // Para ajustar o RTC na primeira vez:
  // 1) Descomente a linha abaixo
  // 2) Faça upload
  // 3) Comente a linha novamente
  // 4) Faça upload mais uma vez
  // rtc.adjust(DateTime(F(__DATE__), F(__TIME__)));

  byte numDigits = 4;
  byte digitPins[] = {7, 8, 9, 10};
  byte segmentPins[] = {2, 3, 4, 5, 11, 12, 13, 6};
  bool resistorsOnSegments = false;
  byte hardwareConfig = COMMON_CATHODE;
  bool updateWithDelays = false;
  bool leadingZeros = false;
  bool disableDecPoint = true;

  sevseg.begin(hardwareConfig, numDigits, digitPins, segmentPins,
               resistorsOnSegments, updateWithDelays, leadingZeros, disableDecPoint);
  sevseg.setBrightness(100);
  sevseg.setNumber(1234, 1);
  delayWithUpdate(1000);
  sevseg.setNumber(8888, 1);
  delayWithUpdate(1000);
}

void loop() {
  sevseg.refreshDisplay();
  DateTime now = rtc.now();
  tsPassed = now - dtBegin;

  static uint32_t nextReportMillis = 0;
  static uint16_t prevDaysPassed = 0;

  if (tsPassed.days() != prevDaysPassed) {
    prevDaysPassed = tsPassed.days();
    sevseg.setNumber(prevDaysPassed, 0);
  }

  if (millis() > nextReportMillis) {
    showInfo(now);
    nextReportMillis = millis() + 5000;
  }
}

Esquemático

Use o link abaixo para visualizar o esquema no Circuito.io:

https://www.circuito.io/app?components=512,11021

  1. Copie e cole o link no navegador.
  2. Clique em "Add Components".
  3. Digite: RTC (adicione); 7 segment display 20mm (escolha genérico, não SparkFun).
  4. Siga o diagrama e conecte cada pino usando os jumpers.

Presente de Dia dos Namorados: Contador DIY de Dias Juntos

Processo de manufatura

  1. Dados Digital com Arduino: Gere Números Aleatórios 1-6 em LCD 16x2
  2. Construa um Homem de Ferro com Arduino: Componentes, Sensores e Guia Passo a Passo
  3. Find Me: Localizador Inteligente de Objetos com Arduino e Bluetooth
  4. Construa um Braço Robótico 3D Impresso Funcional com Arduino – Guia Passo a Passo
  5. Controlador de Umidificador DIY com Arduino e Relé – Configuração Segura de Alta Tensão
  6. Contador Inteligente de Vagas: Rastreamento de Veículos em Tempo Real com Arduino, Processing e PHP
  7. Contador de RPM Arduino de Alta Velocidade com Algoritmo Inovador
  8. Jogo Pong Neon em Matriz NeoPixel com Arduino Nano
  9. Volante Joystick Arduino Personalizado para Jogos
  10. Construa um Receptor FM Potente com Arduino e Módulo TEA5767